10 REM CENTRALINA ACCENSIONE AUTOMOBILE, FIAT X1/9
20 REM CON IL COMMODORE 64, V 1.0
30 REM (C) 2021, AMEDEO VALOROSO, WWW.VALOROSO.IT

50 REM STATO INIZIALE USCITE (SPENTE CON SICUREZZA SU AVVIAMENTO)
60 POKE 56579,8
80 REM DISABILITA RUN/STOP, RESTORE E SHIFT-COMMODORE
90 POKE 808,234: POKE 657,128

100 REM INTESTAZIONE E SVUOTAMENTO BUFFER TASTIERA
110 GOSUB 1000
120 POKE 198,0
130 PRINT

200 REM RICHIESTA PASSWORD ACCENSIONE
210 PRINT "    DIGITARE PASSWORD DI ACCENSIONE"
220 PW$=""
230 INPUT "    ";PW$
240 IF PW$<>"CIAO" THEN GOTO 100

300 REM ACCENSIONE QUADRO, MOTORINO AVVIAMENTO SPENTO
310 GOSUB 1000
320 POKE 56579,11

400 REM ELENCO COMANDI
410 PRINT
420 PRINT "   {$b0}{$c0:32}{$ae}"
430 PRINT "   {$dd}                                {$dd}"
440 PRINT "   {$dd}   *** UN SOLO AVVIAMENTO ***   {$dd}"
450 PRINT "   {$dd}  F1 - MOTORINO AVVIAMENTO ON   {$dd}"
460 PRINT "   {$dd}  F3 - MOTORINO AVVIAMENTO OFF  {$dd}"
470 PRINT "   {$dd}                                {$dd}"
480 PRINT "   {$dd}  F7 - SPEGNI QUADRO            {$dd}"
490 PRINT "   {$dd}                                {$dd}"
500 PRINT "   {$ad}{$c0:32}{$bd}"
510 PRINT: PRINT

590 OC=64: MA=0
600 REM CICLO PRINCIPALE E COMANDI DA TASTIERA
610 C=PEEK(197)
620 IF C=OC THEN GOTO 600
630 OC=C
640 PRINT " TASTO" STR$(C) "     {left:4}";

700 IF C=3 THEN GOTO 4000
710 IF C=4 THEN GOSUB 3000
720 IF C=5 THEN GOSUB 2000
790 PRINT "OK{up}"

800 GOTO 600

1000 REM INTESTAZIONE
1010 PRINT "{clear}"
1020 PRINT: PRINT
1030 PRINT " {$b0}{$c0:36}{$ae}"
1040 PRINT " {$dd}     CENTRALINA FIAT X1/9 - C64     {$dd}"
1050 PRINT " {$dd}           WWW.VALOROSO.IT          {$dd}"
1060 PRINT " {$ad}{$c0:36}{$bd}"
1070 RETURN

2000 REM SPEGNE MOTORINO DI AVVIAMENTO
2010 POKE 56579,3
2020 FOR T=1 TO 150: NEXT T
2030 POKE 56579,11
2040 RETURN

3000 REM ACCENDE MOTORINO DI AVVIAMENTO
3010 IF MA=1 THEN RETURN
3020 POKE 56579,3
3030 FOR T=1 TO 150: NEXT T
3040 POKE 56579,7
3050 MA=1
3060 RETURN

4000 REM SPEGNE QUADRO
4010 POKE 56579,0
4020 FOR T=1 TO 150: NEXT T
4030 GOTO 10