10 REM STUFETTA ELETTRICA PER COMMODORE 64, V 1.0
20 REM (C) 2020, AMEDEO VALOROSO, WWW.VALOROSO.IT

30 PRINT "{clear}"
40 PRINT: PRINT
50 PRINT " {$b0}{$c0:36}{$ae}"
60 PRINT " {$dd} COMMODORE 64    STUFETTA ELETTRICA {$dd}"
70 PRINT " {$dd}           WWW.VALOROSO.IT          {$dd}"
80 PRINT " {$ad}{$c0:36}{$bd}"

100 REM ELENCO COMANDI
110 PRINT
120 PRINT "   {$b0}{$c0:32}{$ae}"
130 PRINT "   {$dd}                                {$dd}"
140 PRINT "   {$dd}    1 -  SOLO VENTOLA           {$dd}"
150 PRINT "   {$dd}    2 -  SCALDA, POTENZA 1      {$dd}"
160 PRINT "   {$dd}    3 -  SCALDA, POTENZA 2      {$dd}"
170 PRINT "   {$dd}    0 -  SPEGNI                 {$dd}"
180 PRINT "   {$dd}    X -  ESCI DAL PROGRAMMA     {$dd}"
200 PRINT "   {$dd}                                {$dd}"
210 PRINT "   {$ad}{$c0:32}{$bd}"

300 REM STATO INIZIALE USCITE (SPENTE)
310 POKE 56579,0
320 S=0: P=1

400 REM RIQUADRO DEGLI STATI
410 PRINT
420 PRINT " {$b0}{$c0:36}{$ae}"
430 PRINT " {$dd}      TERMOVENTILATORE SPENTO       {$dd}"
480 PRINT " {$ad}{$c0:36}{$bd}"

600 REM CICLO PRINCIPALE E COMANDI DA TASTIERA
610 GET C$
620 IF C$="1" THEN GOSUB 2000
630 IF C$="2" THEN GOSUB 2100
640 IF C$="3" THEN GOSUB 2200
650 IF C$="0" THEN GOSUB 2300
680 IF C$="X" THEN GOTO 4000

700 REM COMANDI DA JOYSTICK, PORTA 2
710 A=PEEK(56320)
720 IF B=A THEN GOTO 600
730 B=A
740 IF A=127 THEN GOTO 600

750 REM SU = INCREMENTO POTENZA; GIU = DECREMENTO POTENZA
760 IF A=126 THEN IF S>0 THEN P=P+1: IF P>3 THEN P=3
770 IF A=125 THEN IF S>0 THEN P=P-1: IF P<1 THEN P=1
780 REM FIRE = ACCENDI E SPEGNI
790 IF A=111 THEN IF S>0 THEN S=0: GOTO 900
800 IF A=111 THEN IF S=0 THEN S=1: GOTO 900

900 IF S=0 THEN GOSUB 2300
910 IF S=1 AND P=1 THEN GOSUB 2000
920 IF S=1 AND P=2 THEN GOSUB 2100
930 IF S=1 AND P=3 THEN GOSUB 2200

990 GOTO 600

2000 REM ACCENDI VENTOLA
2010 PRINT "{up:2}";
2020 PRINT " {$dd}{yellow}          VENTOLA   ACCESA          {ltblue}{$dd}"
2030 PRINT
2050 S=1: P=1
2080 POKE 56579,1
2090 RETURN

2100 REM ACCENDI, POTENZA 1
2110 PRINT "{up:2}";
2120 PRINT " {$dd}{yellow} TERMOVENTILATORE ACCESO, POTENZA 1 {ltblue}{$dd}"
2130 PRINT
2150 S=1:P=2
2180 POKE 56579,3
2190 RETURN

2200 REM ACCENDI, POTENZA 2
2210 PRINT "{up:2}";
2220 PRINT " {$dd}{yellow} TERMOVENTILATORE ACCESO, POTENZA 2 {ltblue}{$dd}"
2230 PRINT
2250 S=1:P=3
2280 POKE 56579,7
2290 RETURN

2300 REM SPEGNI STUFETTA
2310 PRINT "{up:2}";
2320 PRINT " {$dd}      TERMOVENTILATORE SPENTO       {$dd}"
2330 PRINT
2350 S=0
2380 POKE 56579,0
2390 RETURN


4000 REM USCITA DAL PROGRAMMA
4010 PRINT "{up:2}";
4020 PRINT " {$dd}      CIAO DA {yellow}AMEDEO VALOROSO{ltblue} !     {$dd}"
4030 PRINT
4050 POKE 56579,0
4080 END